SimpleProxy/build.gradle.kts at main · AzisabaNetwork/SimpleProxy · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
plugins {
    java
    id("com.gradleup.shadow") version "9.1.0"
    `java-library`
    `maven-publish`
}

group = "net.azisaba.simpleproxy"
version = "2.1.2"

extra.set("log4jVersion", "2.25.4")

java {
    toolchain.languageVersion.set(JavaLanguageVersion.of(11))
}

subprojects {
    apply {
        plugin("java")
        plugin("com.gradleup.shadow")
        plugin("java-library")
        plugin("maven-publish")
    }

    group = parent!!.group
    version = parent!!.version

    repositories {
        mavenCentral()
    }

    dependencies {
        compileOnlyApi("org.jetbrains:annotations:26.1.0")
        testImplementation("org.junit.jupiter:junit-jupiter-api:5.13.4")
        testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.13.4")
        testRuntimeOnly("org.junit.platform:junit-platform-launcher:1.13.4")
    }

    tasks {
        test {
            useJUnitPlatform()
        }

        processResources {
            from(
                sourceSets.main
                    .get()
                    .resources.srcDirs,
            ) {
                include("**")
                val tokenReplacementMap =
                    mapOf(
                        "version" to project.version,
                        "name" to project.parent!!.name,
                    )
                filter<org.apache.tools.ant.filters.ReplaceTokens>("tokens" to tokenReplacementMap)
            }
            filteringCharset = "UTF-8"
            duplicatesStrategy = DuplicatesStrategy.INCLUDE
            from(projectDir) { include("LICENSE") }
        }

        jar {
            manifest {
                attributes(
                    "Main-Class" to "net.azisaba.simpleproxy.proxy.Main",
                    "Multi-Release" to true,
                )
            }
        }
    }
}

allprojects {
    java {
        toolchain {
            languageVersion.set(JavaLanguageVersion.of(8))
        }

        withJavadocJar()
        withSourcesJar()
    }

    val javaComponent = components["java"] as AdhocComponentWithVariants
    javaComponent.withVariantsFromConfiguration(configurations["sourcesElements"]) {
        skip()
    }

    publishing {
        repositories {
            maven {
                name = "repo"
                credentials(PasswordCredentials::class)
                url =
                    uri(
                        if (project.version.toString().endsWith("SNAPSHOT")) {
                            project.findProperty("deploySnapshotURL")
                                ?: System.getProperty("deploySnapshotURL", "https://repo.azisaba.net/repository/maven-snapshots/")
                        } else {
                            project.findProperty("deployReleasesURL")
                                ?: System.getProperty("deployReleasesURL", "https://repo.azisaba.net/repository/maven-releases/")
                        },
                    )
            }
        }

        publications {
            create<MavenPublication>("mavenJava") {
                from(components["java"])
                artifact(tasks.getByName("sourcesJar"))
            }
        }
    }
}