XRay-Mod/build.gradle at main · AdvancedXRay/XRay-Mod · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
plugins {
    id 'java-library'
    id 'net.fabricmc.fabric-loom' version '1.15-SNAPSHOT' apply(false)
    id 'net.neoforged.moddev' version '2.0.141' apply(false)
    id "me.modmuss50.mod-publish-plugin" version "1.1.0"
}

tasks.named('wrapper', Wrapper).configure {
    distributionType = Wrapper.DistributionType.BIN
}

allprojects {
    apply plugin: 'idea'
    apply plugin: 'java-library'
    apply plugin: 'maven-publish'

    version = mod_version
    group = 'pro.mikey.mods'

    tasks.withType(JavaCompile).configureEach {
        options.encoding = 'UTF-8'
        options.release = 25
    }

    idea {
        module {
            downloadSources = true
            downloadJavadoc = true
        }
    }

//    jar {
//        from(rootProject.file("LICENSE").toString()) {
//            rename { "${it}_${project.archivesBaseName}" }
//        }
//    }
}

subprojects {
    base {
        archivesName = "advanced-xray-$project.name"
    }

    if (project.name != "common") {
        dependencies {
            api project(":common")
        }

        jar {
            from project(":common").sourceSets.main.output
        }
    }

    def replaceProperties = [
            minecraft_version: minecraft_version,
            minecraft_version_range: minecraft_version_range.replace("[%base]", minecraft_version),
            forge_version_range: neoforge_version_range,
            version: version,
    ]

    processResources {
        inputs.properties replaceProperties

        filesMatching(["META-INF/neoforge.mods.toml", "fabric.mod.json", "META-INF/mods.toml"]) {
            expand replaceProperties
        }
    }

    publishing {
        publications {
            register("mavenJava" + project.name, MavenPublication) {
                artifactId = "advanced-xray" + (project.name !== "common" ? "-" + project.name : "")
                from components.java
            }
        }

        repositories {
            def token = providers.environmentVariable("SAPS_TOKEN");
            if (token.isPresent()) {
                maven {
                    url "https://maven.saps.dev/releases"
                    credentials {
                        username = "mikeymods"
                        password = token.get()
                    }
                }
            }
        }
    }
}

publishMods {
    dryRun = providers.environmentVariable("CURSE_DEPLOY_TOKEN").getOrNull() == null
    changelog = file("./CHANGELOG.md").text
    version = "${mod_version}"
    type = STABLE

    def createOptions = (String platform, String taskName) -> {
        publishOptions {
            file = project.provider { project(":$platform").tasks[taskName] }.flatMap { it.archiveFile }
            displayName = "[${platform.toUpperCase()}] Advanced XRay ${mod_version}"
            modLoaders.add(platform.toLowerCase())
        }
    }

    def curseForgeOptions = curseforgeOptions {
        accessToken = providers.environmentVariable("CURSE_DEPLOY_TOKEN")
        minecraftVersions.add("${minecraft_version}")
        javaVersions.add(JavaVersion.VERSION_25)
    }

    curseforge("curseforgeNeoforge") {
        from(curseForgeOptions, createOptions("neoforge", "jar"))
        projectId = "256256"
    }

    curseforge("curseforgeFabric") {
        from(curseForgeOptions, createOptions("fabric", "jar"))
        projectId = "444663"
    }

    github {
        accessToken = providers.environmentVariable("GITHUB_TOKEN")
        repository = "AdvancedXRay/XRay-Mod"
        commitish = providers.environmentVariable("GITHUB_SHA").orElse("dryRun")
        tagName = providers.environmentVariable("GITHUB_REF_NAME").orElse("dryRun")

        file = project.provider { project(":neoforge").tasks.jar }.flatMap { it.archiveFile }
        additionalFiles.from project.provider { project(":fabric").tasks.jar }.flatMap { it.archiveFile }
    }
}